home *** CD-ROM | disk | FTP | other *** search
/ Aminet 37 / Aminet 37 (2000)(Schatztruhe)[!][Jun 2000].iso / Aminet / dev / lang / sofa.lha / sofa / smalleiffel / lib_se / class_name.e < prev    next >
Text File  |  2000-03-25  |  5KB  |  163 lines
  1. --          This file is part of SmallEiffel The GNU Eiffel Compiler.
  2. --          Copyright (C) 1994-98 LORIA - UHP - CRIN - INRIA - FRANCE
  3. --            Dominique COLNET and Suzanne COLLIN - colnet@loria.fr
  4. --                       http://SmallEiffel.loria.fr
  5. -- SmallEiffel is  free  software;  you can  redistribute it and/or modify it
  6. -- under the terms of the GNU General Public License as published by the Free
  7. -- Software  Foundation;  either  version  2, or (at your option)  any  later
  8. -- version. SmallEiffel is distributed in the hope that it will be useful,but
  9. -- WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  10. -- or  FITNESS FOR A PARTICULAR PURPOSE.   See the GNU General Public License
  11. -- for  more  details.  You  should  have  received a copy of the GNU General
  12. -- Public  License  along  with  SmallEiffel;  see the file COPYING.  If not,
  13. -- write to the  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  14. -- Boston, MA 02111-1307, USA.
  15. --
  16. class CLASS_NAME
  17.    --
  18.    -- To store the base class name of a class.
  19.    --
  20.  
  21. inherit NAME;
  22.  
  23. creation make, unknown_position
  24.  
  25. feature
  26.  
  27.    start_position: POSITION;
  28.  
  29.    to_string: STRING;
  30.  
  31. feature {NONE}
  32.  
  33.    make(n: STRING; sp: like start_position) is
  34.       require
  35.          n = string_aliaser.item(n)
  36.       do
  37.          to_string := n;
  38.          start_position := sp;
  39.       ensure
  40.          start_position = sp;
  41.          to_string = n
  42.       end;
  43.  
  44.    unknown_position(n: STRING) is
  45.       require
  46.          n = string_aliaser.item(n)
  47.       do
  48.          to_string := n;
  49.       ensure
  50.          to_string = n
  51.       end;
  52.  
  53. feature
  54.  
  55.    is_subclass_of(other: CLASS_NAME): BOOLEAN is
  56.       require
  57.          to_string /= other.to_string
  58.       do
  59.          if as_none = to_string then
  60.             Result := true;
  61.          elseif as_any = other.to_string then
  62.             Result := true;
  63.          elseif as_none = other.to_string then
  64.          else
  65.             Result := base_class.is_subclass_of(other.base_class);
  66.          end;
  67.       end;
  68.  
  69.    predefined: BOOLEAN is
  70.          -- All following classes are handled in a special way
  71.          -- by the TYPE_* corresponding class.
  72.       do
  73.          Result := (as_any = to_string or else
  74.                     as_array = to_string or else
  75.                     as_boolean = to_string or else
  76.                     as_character = to_string or else
  77.                     as_double = to_string or else
  78.                     as_integer = to_string or else
  79.                     as_none = to_string or else
  80.                     as_pointer = to_string or else
  81.                     as_real = to_string or else
  82.                     as_string = to_string);
  83.       end;
  84.  
  85.    to_runnable: TYPE is
  86.          -- Return the corresponding simple (not generic) run type.
  87.       do
  88.          if as_any = to_string then
  89.             !TYPE_ANY!Result.make(start_position);
  90.          elseif as_boolean = to_string then
  91.             !TYPE_BOOLEAN!Result.make(start_position);
  92.          elseif as_character = to_string then
  93.             !TYPE_CHARACTER!Result.make(start_position);
  94.          elseif as_double = to_string then
  95.             !TYPE_DOUBLE!Result.make(start_position);
  96.          elseif as_integer = to_string then
  97.             !TYPE_INTEGER!Result.make(start_position);
  98.          elseif as_none = to_string then
  99.             !TYPE_NONE!Result.make(start_position);
  100.          elseif as_pointer = to_string then
  101.             !TYPE_POINTER!Result.make(start_position);
  102.          elseif as_real = to_string then
  103.             !TYPE_REAL!Result.make(start_position);
  104.          elseif as_string = to_string then
  105.             !TYPE_STRING!Result.make(start_position);
  106.          else
  107.             !TYPE_CLASS!Result.make(Current);
  108.          end;
  109.       end;
  110.  
  111.    base_class: BASE_CLASS is
  112.       do
  113.          Result := small_eiffel.base_class(Current);
  114.       end;
  115.  
  116.    is_a(other: like Current): BOOLEAN is
  117.       require
  118.          other /= Void;
  119.          eh.is_empty;
  120.       local
  121.          to_string2: STRING;
  122.          bc1, bc2: like base_class;
  123.       do
  124.          to_string2 := other.to_string;
  125.          if as_any = to_string2 then
  126.             Result := true;
  127.          elseif to_string = to_string2 then
  128.             Result := true;
  129.          elseif as_none = to_string2 then
  130.          else
  131.             bc1 := base_class;
  132.             bc2 := other.base_class;
  133.             if bc1 = Void then
  134.                eh.append("Unable to load ");
  135.                eh.append(to_string);
  136.                error(start_position,fz_dot);
  137.             elseif bc2 = Void then
  138.                eh.append("Unable to load ");
  139.                eh.append(to_string2);
  140.                error(start_position,fz_dot);
  141.             else
  142.                Result := bc1.is_subclass_of(bc2);
  143.             end;
  144.          end;
  145.       end;
  146.  
  147.    pretty_print is
  148.       do
  149.          fmt.put_string(to_string);
  150.       end;
  151.  
  152. feature {EIFFEL_PARSER}
  153.  
  154.    set_accurate_position(sp: like start_position) is
  155.       do
  156.          start_position := sp;
  157.       ensure
  158.          start_position = sp
  159.       end;
  160.  
  161. end -- CLASS_NAME
  162.  
  163.